# Excel – Convert Numbers to English Words – Create Macros

Recently I was asked to create a payment form that would be auto generated by changing one parameter, filling out all forms from separate spread sheet using “VLOOKUP”. Next to the numerical value of the total payment, displaying the value in English words was required.

It’s quite obvious that converting a numeric value into English words in Excel requires to have a function written in Microsoft Visual Basic as far as there is no built-in function for this task.

To start inserting VB code into Excel you have to first start Excel and then enter VB Editor by pressing OPTION+FN+F11 (on a Mac) and ALT+F11 (on Windows). The VB editor slightly differs from Mac to Windows.

From inside the Visual Basic Editor navigate to menu on the left side select “This Workbook”, right-click it and from there select Insert -> Module. Module section will appear right underneath of “Microsoft Excel Objects” section, expand it and select module. Next, in the VB editor main area paste the code (given below).

Paste the below code into the editor window:

```Option Explicit
'Main Function
Function SpellNumber(ByVal MyNumber)
Dim Dollars, Cents, Temp
Dim DecimalPlace, Count
ReDim Place(9) As String
Place(2) = " Thousand "
Place(3) = " Million "
Place(4) = " Billion "
Place(5) = " Trillion "
' String representation of amount.
MyNumber = Trim(Str(MyNumber))
' Position of decimal place 0 if none.
DecimalPlace = InStr(MyNumber, ".")
' Convert cents and set MyNumber to dollar amount.
If DecimalPlace > 0 Then
Cents = GetTens(Left(Mid(MyNumber, DecimalPlace + 1) & _
"00", 2))
MyNumber = Trim(Left(MyNumber, DecimalPlace - 1))
End If
Count = 1
Do While MyNumber <> ""
Temp = GetHundreds(Right(MyNumber, 3))
If Temp <> "" Then Dollars = Temp & Place(Count) & Dollars
If Len(MyNumber) > 3 Then
MyNumber = Left(MyNumber, Len(MyNumber) - 3)
Else
MyNumber = ""
End If
Count = Count + 1
Loop
Select Case Dollars
Case ""
Dollars = "No Dollars"
Case "One"
Dollars = "One Dollar"
Case Else
Dollars = Dollars & " Dollars"
End Select
Select Case Cents
Case ""
Cents = " and No Cents"
Case "One"
Cents = " and One Cent"
Case Else
Cents = " and " & Cents & " Cents"
End Select
SpellNumber = Dollars & Cents
End Function

' Converts a number from 100-999 into text
Function GetHundreds(ByVal MyNumber)
Dim Result As String
If Val(MyNumber) = 0 Then Exit Function
MyNumber = Right("000" & MyNumber, 3)
' Convert the hundreds place.
If Mid(MyNumber, 1, 1) <> "0" Then
Result = GetDigit(Mid(MyNumber, 1, 1)) & " Hundred "
End If
' Convert the tens and ones place.
If Mid(MyNumber, 2, 1) <> "0" Then
Result = Result & GetTens(Mid(MyNumber, 2))
Else
Result = Result & GetDigit(Mid(MyNumber, 3))
End If
GetHundreds = Result
End Function

' Converts a number from 10 to 99 into text.
Function GetTens(TensText)
Dim Result As String
Result = ""           ' Null out the temporary function value.
If Val(Left(TensText, 1)) = 1 Then   ' If value between 10-19...
Select Case Val(TensText)
Case 10: Result = "Ten"
Case 11: Result = "Eleven"
Case 12: Result = "Twelve"
Case 13: Result = "Thirteen"
Case 14: Result = "Fourteen"
Case 15: Result = "Fifteen"
Case 16: Result = "Sixteen"
Case 17: Result = "Seventeen"
Case 18: Result = "Eighteen"
Case 19: Result = "Nineteen"
Case Else
End Select
Else                                 ' If value between 20-99...
Select Case Val(Left(TensText, 1))
Case 2: Result = "Twenty "
Case 3: Result = "Thirty "
Case 4: Result = "Forty "
Case 5: Result = "Fifty "
Case 6: Result = "Sixty "
Case 7: Result = "Seventy "
Case 8: Result = "Eighty "
Case 9: Result = "Ninety "
Case Else
End Select
Result = Result & GetDigit _
(Right(TensText, 1))  ' Retrieve ones place.
End If
GetTens = Result
End Function

' Converts a number from 1 to 9 into text.
Function GetDigit(Digit)
Select Case Val(Digit)
Case 1: GetDigit = "One"
Case 2: GetDigit = "Two"
Case 3: GetDigit = "Three"
Case 4: GetDigit = "Four"
Case 5: GetDigit = "Five"
Case 6: GetDigit = "Six"
Case 7: GetDigit = "Seven"
Case 8: GetDigit = "Eight"
Case 9: GetDigit = "Nine"
Case Else: GetDigit = ""
End Select
End Function```

When the code is saved you can directly use the function SpellNumber just as you would use any other Excel built-in function.

Usage 1:
You can change 32.50 into “Thirty Two Dollars and Fifty Cents” by entering the following formula into a cell: =SpellNumber(32.50)

Usage 2:
You can refer to other cells in the workbook. For example, enter the number 32.50 into cell A1, and type the following formula into another cell: =SpellNumber(C1)

### Changing the function:

When implemented, the function’s output for value 67453.51 includes cents – “and fifty cents”.
In order to get rid of floating points being converted to words you can simply remove or comment the following lines in the switch statement:

```Select Case Cents
Case ""
Cents = " and No Cents"
Case "One"
Cents = " and One Cent"
Case Else
Cents = " and " & Cents & " Cents"
End Select```

### Saving the file:

When trying to save the file you will be given a dialog:

You will have to set .xlsm file format for your Excel file to keep the macros. Otherwise you will have to do all the steps described above each time you open the file you just created. From the Save As dialog select File Format of Excel Macro-Enabled Workbook (.xlsm).

### Conclusion

That’s it! Hopefully this function and changes to it will come handy if you want to auto generate some payment documents (invoices, debit notes).

This code can also be found on Microsoft Support Page but as far as there are no screenshots provided it was not straightforward to implement and even got into a headache on a Mac.